<%@ LANGUAGE = VBScript%>
<%
Class ASPEdit	
	Public ToolbarLayout
	Public ID
	Private s_width	
	Private s_height
	Private s_Text
	private s_filespath
	private s_allowupload	
	private s_allowpastehtml
	private s_stylesheetpath	
	private s_imagegallerypath	
	private s_flashpath	
	private s_documentpath	
	private s_showBottomBar
	private s_showHtmlMode
	private s_showpreviewmode
	private s_showlogo
	Private s_maxImageSize
	Private s_maxFlashSize
	Private s_maxDocumentSize
	Private s_template
	Private s_disableitemlist
	Private s_autoconfigure
	Private s_helpurl
	Private s_styledropdownMenuNames
	Private s_styledropdownMenuList
	Private s_codesnippetdropdownMenuNames
	Private s_codesnippetdropdownMenuList
	Private s_imagesdropdownMenuNames
	Private s_imagesdropdownMenuList
	Private s_linksdropdownMenuNames
	Private s_linksdropdownMenuList
	private s_renderClientScript
	private s_enableclientscript	
	private s_textareaCols
	private s_textareaRows
	private s_subsequent
	private s_logotext
	private s_ParagraphsDropDownWidth
	private s_SizesDropDownWidth	
	private s_ZoomsDropDownWidth	
	private s_StylesDropDownWidth
	private s_CodeSnippetsDropDownWidth
	private s_ImagesDropDownWidth
	private s_FontsDropDownWidth
	private s_LinksDropDownWidth
	private s_FontSizesList
	private s_ZoomsList
	private s_FontFacesList
	private s_ParagraphsList
	
	Public CustomAddons	
	Public Property Get ParagraphsList
		if s_ParagraphsList = "" then
			ParagraphsList = "Normal,Heading 1,Heading 2,Heading 3,Heading 4,Heading 5,Heading 6,Address,Formatted,Definition Term"
		else 
			ParagraphsList = s_ParagraphsList
		End if
	End Property	
	
	Public Property Let ParagraphsList(list)
		s_ParagraphsList = list
	End Property
	
	Public Property Get FontFacesList
		if s_FontFacesList = "" then
			FontFacesList = "Arial,Verdana,Comic Sans MS,Courier,Georgia,Impact,Lucida Console,Tahoma,Times New Roman,Wingdings"
		else 
			FontFacesList = s_FontFacesList
		End if
	End Property	
	
	Public Property Let FontFacesList(list)
		s_FontFacesList = list
	End Property
	
	Public Property Get ZoomsList
		if s_ZoomsList = "" then
			ZoomsList = "500%,200%,125%,100%,90%,85%,80%,75%,50%,25%"
		else 
			ZoomsList = s_ZoomsList
		End if
	End Property	
	
	Public Property Let ZoomsList(list)
		s_ZoomsList = list
	End Property
	
	Public Property Get FontSizesList
		if s_FontSizesList = "" then
			FontSizesList = "1,2,3,4,5,6,7"
		else 
			FontSizesList = s_FontSizesList
		End if
	End Property	
	
	Public Property Let FontSizesList(list)
		s_FontSizesList = list
	End Property
	
	Public Property Get LinksDropDownWidth
		if s_LinksDropDownWidth = "" then
			LinksDropDownWidth = "80"
		else 
			LinksDropDownWidth = s_LinksDropDownWidth
		End if
	End Property	
	
	Public Property Let LinksDropDownWidth(width)
		s_LinksDropDownWidth = width
	End Property
	
	Public Property Get ParagraphsDropDownWidth
		if s_ParagraphsDropDownWidth= "" then
			ParagraphsDropDownWidth = 100
		else 
			ParagraphsDropDownWidth = s_ParagraphsDropDownWidth
		End if
	End Property	
	
	Public Property Let ParagraphsDropDownWidth(width)
		s_ParagraphsDropDownWidth = width
	End Property
	
	Public Property Get SizesDropDownWidth
		if s_SizesDropDownWidth = "" then
			SizesDropDownWidth = 60
		else 
			SizesDropDownWidth = s_SizesDropDownWidth
		End if
	End Property
	
	Public Property Let SizesDropDownWidth(width)
		s_SizesDropDownWidth = width
	End Property	
	
	Public Property Get ZoomsDropDownWidth
		if s_ZoomsDropDownWidth = "" then
			ZoomsDropDownWidth = 60
		else 
			ZoomsDropDownWidth = s_ZoomsDropDownWidth
		End if
	End Property
	
	Public Property Let ZoomsDropDownWidth(width)
		s_ZoomsDropDownWidth = width
	End Property
	
	Public Property Get StylesDropDownWidth
		if s_StylesDropDownWidth = "" then
			StylesDropDownWidth = 80
		else 
			StylesDropDownWidth = s_StylesDropDownWidth
		End if
	End Property
	
	Public Property Let StylesDropDownWidth(width)
		s_StylesDropDownWidth = width
	End Property
	
	Public Property Get CodeSnippetsDropDownWidth
		if s_CodeSnippetsDropDownWidth = "" then
			CodeSnippetsDropDownWidth = 110
		else 
			CodeSnippetsDropDownWidth = s_CodeSnippetsDropDownWidth
		End if
	End Property
	
	Public Property Let CodeSnippetsDropDownWidth(width)
		s_CodeSnippetsDropDownWidth = width
	End Property	
	
	Public Property Get ImagesDropDownWidth
		if s_ImagesDropDownWidth = "" then
			ImagesDropDownWidth = 80
		else 
			ImagesDropDownWidth = s_ImagesDropDownWidth
		End if
	End Property
	
	Public Property Let ImagesDropDownWidth(width)
		s_ImagesDropDownWidth = width
	End Property
	
	Public Property Get FontsDropDownWidth
		if s_FontsDropDownWidth = "" then
			FontsDropDownWidth = 110
		else 
			FontsDropDownWidth = s_FontsDropDownWidth
		End if
	End Property
	
	Public Property Let FontsDropDownWidth(width)
		s_FontsDropDownWidth = width
	End Property
		
	Public Property Let Width(editor_width)
		s_width = editor_width
	End Property
	
	Public Property Let Height(editor_height)
		s_height = editor_height
	End Property
	
	Public Property Let TextareaCols(textarea_Cols)
		s_textareaCols = textarea_Cols
	End Property
	
	Public Property Let TextareaRows(textarea_Rows)
		s_textareaRows = textarea_Rows
	End Property
	
	Public Property Let Text(initialText)
		s_Text = initialText
	End Property
	
	Public Property Let MaxImageSize(size)
		s_maxImageSize = size
	End Property
	
	Public Property Let MaxDocumentSize(size)
		s_maxDocumentSize = size
	End Property
	
	Public Property Let MaxFlashSize(size)
		s_maxFlashSize = size
	End Property
	
	Public Property Get Text
		Text = Request.Form(ID&":HTMLContent")
	End Property	
	
	Public Property Get LogoText
		if s_logotext= "" then
			LogoText = "<a href=""Http://ASPEdit.Net"" style=""text-decoration:none;color:gray;font-family:Arial;font-size:10px;"">ASPEdit V1.0 2003</a>&nbsp;&nbsp;"
		else 
			LogoText = s_logotext
		End if
	End Property	
	
	Public Property Let LogoText(text)
		s_logotext = text
	End Property		
	
	Public Property Let FilesPath(editor_filespath)
		If Right(editor_filespath,1) = "/" Then
			editor_filespath = Left(editor_filespath, Len(editor_filespath)-1)
		End If
		s_filespath = editor_filespath
	End Property
	
	Public Property Let AllowUpload(yesornot)
		s_allowupload = yesornot
	End Property	
	
	Public Property Let AllowPasteHtml(yesornot)
		s_allowpastehtml = yesornot
	End Property	
	
	Public Property Let subsequent(yesornot)
		s_subsequent = yesornot
	End Property
	
	Public Property Let EnableClientScript(trueornot)
		s_enableclientscript = trueornot
	End Property
	
	Public Property Let ImageGalleryPath(path)
		s_imagegallerypath = path
	End Property
	
	Public Property Get ImageGalleryPath
		if s_imagegallerypath= "" then
			ImageGalleryPath = "/uploads"
		else 
			ImageGalleryPath = s_imagegallerypath
		End If
	End Property
	
	Public Property Let FlashPath(path)
		s_flashpath = path
	End Property
	
	Public Property Get FlashPath
		if s_flashpath= "" then
			FlashPath = "/uploads"
		else 
			FlashPath = s_flashpath
		End If
	End Property
	
	Public Property Let DocumentPath(path)
		s_documentpath = path
	End Property
	
	Public Property Get DocumentPath
		if s_documentpath= "" then
			DocumentPath = "/uploads"
		else 
			DocumentPath = s_documentpath
		End If
	End Property
	
	Public Property Let StyleSheetPath(path)
		s_stylesheetpath = path
	End Property	
	
	Public Property Let HelpUrl(path)
		s_helpurl = path
	End Property
		
	Public Property Let Template(Input_template)
		s_template = Input_template
	End Property	
		
	Public Property Let DisableItemList(Input_list)
		s_disableitemlist = Input_list
	End Property	
	
	Public Property Let AutoConfigure(Input_autoconfigure)
		s_autoconfigure = Input_autoconfigure
	End Property
	
	Public Property Let ShowBottomBar(yesornot)
		s_showBottomBar = yesornot
	End Property
	
	Public Property Let ShowHtmlMode(yesornot)
		s_showhtmlmode = yesornot
	End Property
	
	Public Property Let ShowPreviewMode(yesornot)
		s_showpreviewmode = yesornot
	End Property
	
	Public Property Let ShowLogo(yesornot)
		s_showlogo = yesornot
	End Property
		
	Public Property Let StyleDropDownMenuNames(input_string)
		s_styledropdownMenuNames = input_string
	End Property
	
	Public Property Let StyleDropDownMenuList(input_string)
		s_styledropdownMenuList = input_string
	End Property
		
	Public Property Let CodeSnippetDropDownMenuNames(input_string)
		s_codesnippetdropdownMenuNames = input_string
	End Property
	
	Public Property Let CodeSnippetDropDownMenuList(input_string)
		s_codesnippetdropdownMenuList = input_string
	End Property
		
	Public Property Let ImagesDropDownMenuNames(input_string)
		s_imagesdropdownMenuNames = input_string
	End Property
	
	Public Property Let ImagesDropDownMenuList(input_string)
		s_imagesdropdownMenuList = input_string
	End Property
		
	Public Property Let LinksDropDownMenuNames(input_string)
		s_linksdropdownMenuNames = input_string
	End Property
	
	Public Property Let LinksDropDownMenuList(input_string)
		s_linksdropdownMenuList = input_string
	End Property
	
	'********************************************************
	' Begin Event Handlers
	'********************************************************

	Private Sub Class_Initialize()
		s_allowupload = true	
		s_allowpastehtml = true
		s_showBottomBar = true
		s_showpreviewmode = true
		s_showlogo = true
		s_showhtmlmode = true
		s_subsequent = false
		s_enableclientscript = true
		s_width = 705
		s_height = 240	
		s_maxImageSize = 100
		s_maxFlashSize = 100
		s_maxDocumentSize = 100
		s_textareaCols = 50
		s_textareaRows = 13
		s_autoconfigure = "default"
	End Sub 
	
	Private Sub DetermineRenderClientScript	
		s_renderClientScript = false		
		If (s_enableclientscript) Then
			dim userAgent
			userAgent = Request.ServerVariables("HTTP_USER_AGENT") 
			If InStr(userAgent, "MSIE") > 0 AND InStr(userAgent, "Windows") > 0  AND InStr(userAgent, "Opera") <= 0 Then
				dim userVersion
				userVersion = CInt(Mid(userAgent, InStr(userAgent, "MSIE") + 5, 1)) 
				s_renderClientScript = (userVersion >= 5.5)
			Else
				s_renderClientScript = False
			End If
		End If
	End Sub

	private Sub Toolbars_Initialize() 		
		if s_template = "" or s_template = null then 			
			Select case Lcase(s_autoconfigure)
				Case "default":
					ToolbarLayout = "Save,Separator,Cut,Copy,Paste,Separator,Undo,Redo,Separator,G_Start,RemoveFormat,SelectAll,Separator,ToggleBorder,AbsolutePosition,G_End,G_Start,Separator,Hr,Link,UnLink,DownloadableFiles,Char,Emotion,InsertText,G_End,G_Start,Separator,ImageGallery,Separator,Forward,Backward,G_End,G_Start,Separator,InsertTable,AddRow,DeleteRow,AddColumn,DeleteColumn,Separator,AddCell,DeleteCell,MergeCell,SplitCell,G_End,G_Start,Break,paragraphDropDown,fontDropDown,sizeDropDown,Bold,Italic,Underline,G_End,G_Start,Separator,JustifyLeft,JustifyCenter,JustifyRight,Separator,FontColor,HighLight,G_End,G_Start,Separator,InsertOrderedList,InsertUnorderedList,Separator,Indent,Outdent,G_End,G_Start,Separator,Subscript,Superscript,Strikethrough,CleanupCode,Help,G_End"			
				Case "enableall":
					ToolbarLayout = "Save,New,Print,Separator,Cut,Copy,Paste,PasteText,PasteWord,Delete,Separator,Undo,Redo,Separator,G_Start,ToggleBorder,AbsolutePosition,G_End,G_Start,Separator,Char,Emotion,InsertText,G_End,G_Start,Separator,ImageGallery,FlashGallery,Separator,Forward,Backward,G_End,G_Start,Separator,InsertTable,AddRow,DeleteRow,AddColumn,DeleteColumn,Separator,AddCell,DeleteCell,MergeCell,SplitCell,G_End,G_Start,Break,Bold,Italic,Underline,G_End,G_Start,Separator,JustifyLeft,JustifyCenter,JustifyRight,JustifyFull,JustifyNone,Separator,FontColor,HighLight,G_End,G_Start,Separator,InsertOrderedList,InsertUnorderedList,Separator,Indent,Outdent,G_End,G_Start,Separator,Subscript,Superscript,Strikethrough,Separator,InsertTime,InsertDate,Separator,Hr,Link,UnLink,DownloadableFiles,Separator,RemoveFormat,SelectAll,SelectNone,CleanupCode,Help,G_End,break,styleDropDown,paragraphDropDown,fontDropDown,sizeDropDown,CodeSnippetDropDown,imagesDropDown,linksDropDown,zoomDropDown"
				Case "simple":
					ToolbarLayout = "fontDropDown,sizeDropDown,Bold,Italic,Underline,Separator,JustifyLeft,JustifyCenter,JustifyRight,Separator,InsertOrderedList,InsertUnorderedList,Separator,Indent,Outdent,Separator,FontColor,HighLight,Separator,Hr,Link,ImageGallery,InsertTable,Separator,Undo,Redo,Help"
				Case "minimal":
					ToolbarLayout = "Bold,Italic,Underline,Separator,JustifyLeft,JustifyCenter,JustifyRight"			
				Case "tablefocus":
					ToolbarLayout = "fontDropDown,sizeDropDown,Bold,Italic,Underline,Separator,JustifyLeft,JustifyCenter,JustifyRight,Separator,InsertTable,AddRow,DeleteRow,AddColumn,DeleteColumn,Separator,AddCell,DeleteCell,MergeCell,SplitCell,Separator,ToggleBorder,AbsolutePosition,Forward,Backward,Separator,Undo,Redo,Help"
				Case "imagefocus":
					ToolbarLayout = "fontDropDown,sizeDropDown,Bold,Italic,Underline,Separator,Cut,Copy,Paste,Separator,Undo,Redo,Separator,ToggleBorder,AbsolutePosition,Separator,Char,Emotion,InsertText,Separator,ImageGallery,externalimage,Separator,Forward,Backward,Separator,JustifyLeft,JustifyCenter,JustifyRight,Help"
				Case Else
					ToolbarLayout = "Bold,Italic,Underline,Separator,JustifyLeft,JustifyCenter,JustifyRight"			
			End Select
			
		else	
			ToolbarLayout = s_template
		end if
	end Sub
	
	Private Sub CreateToolBar()
		
		Dim ToolbarStrings
		Dim i
		
		ToolbarStrings = Split(ToolbarLayout,",")
		For i = 0 to Ubound(Split(ToolbarLayout,","))
			if(s_disableitemlist<> "") then
				
					dim disable_toolbarstrings, j ,found
					found = false
					disable_toolbarstrings = Split(s_disableitemlist,",")
					for j = 0 to Ubound(disable_toolbarstrings) 					
						if (lcase(trim(ToolbarStrings(i))) = lcase(trim(disable_toolbarstrings(j)))) then
							found = true
							Exit for
						else
							found = false
						end if
					next
					
					if(found = false) then
						GetControlFromName(ToolbarStrings(i))
					end if
			else
				GetControlFromName(ToolbarStrings(i))
			end if
		Next
												
	End Sub
	
	Private Sub BuildBottomBar()
	
		Response.Write "<table cellspacing=""0"" cellpadding=""0"" width=""99%"" border=""0""><tr>"
		Response.Write "<td align=left height=""21"" valign=top>"
		Response.Write "<img title=""Normal"" class=""button"" onclick=""EditorView("&ID&",0);"" type=""btn"" src="""&s_filespath&"/design.gif"" border=""0"" />"
		If (s_showhtmlmode) Then
			Response.Write "<img title=""HTML"" class=""button"" onclick=""EditorView("&ID&",1);"" type=""btn"" src="""&s_filespath&"/htmlview.gif"" border=""0"" />"
		End If
		If (s_showpreviewmode) Then
			Response.Write "<img title=""Preview"" class=""button"" onclick=""EditorView("&ID&",2);"" type=""btn"" src="""&s_filespath&"/preview.gif"" border=""0"" />"
		End If
		Response.Write "</td>"
		Response.Write "<td align=right>"
		If (s_showlogo) Then
			Response.Write LogoText
		End If
		Response.Write "</td>"
		Response.Write "</tr></table>"
												
	End Sub
	
	Private Sub AddClientScript()

		Response.Write "<script language=""javascript"">	"
		Response.Write "var "&ID&" =  new _CState('"&ID&"','"&ImageGalleryPath&"','"&s_filespath&"',"&s_MaxImageSize&",'"&s_allowupload&"','"&s_allowpastehtml&"','"&FlashPath&"',"&s_MaxFlashSize&",'"&DocumentPath&"',"&s_maxDocumentSize&");	"
		Response.Write "		"&ID&".Load();	"
		Response.Write "</script>	"
	
	End Sub
	
	Private Sub editorClientScript ()
		If s_subsequent = false then 
			Response.Write ("<script language=""JavaScript"" SRC="""&s_filespath&"/WinIE.js""></script>")
		End if
	End Sub
	
	Private Sub editorStylesheet ()
		If s_stylesheetpath = "" then
			Response.Write "<style type=""text/css"">"
			Response.Write ".button { MARGIN: 1px; VERTICAL-ALIGN: middle; PADDING: 0px}"
			Response.Write ".buttonover {	BORDER-RIGHT: buttonshadow 1px solid; BORDER-TOP: buttonhighlight 1px solid; BORDER-LEFT: buttonhighlight 1px solid; BORDER-BOTTOM: buttonshadow 1px solid; PADDING: 0px; MARGIN: 0px; VERTICAL-ALIGN: middle;}"
			Response.Write ".buttondown {BORDER-RIGHT: buttonhighlight 1px solid; BORDER-TOP: buttonshadow 1px solid; BORDER-LEFT: buttonshadow 1px solid; BORDER-BOTTOM: buttonhighlight 1px solid; MARGIN: 0px; VERTICAL-ALIGN: middle; PADDING: 0px;}"
			Response.Write ".spacer {PADDING-RIGHT: 0px; PADDING-LEFT: 0px; PADDING-BOTTOM: 5px;PADDING-TOP: 0px; MARGIN: 0px; VERTICAL-ALIGN: middle;}"
			Response.Write ".container {PADDING:0px; MARGIN: 0px; BACKGROUND-COLOR: #D4D0C8; TEXT-ALIGN: left; }"
			Response.Write ".editBox {BORDER-LEFT: #8188a3 1px solid; BORDER-RIGHT: #8188a3 1px solid; BORDER-TOP: #8188a3 1px solid; BORDER-BOTTOM: #8188a3 1px solid;  PADDING: 10px; MARGIN: 2px 0px 0px; OVERFLOW: auto; BACKGROUND-COLOR: #ffffff; TEXT-ALIGN: left}"
			Response.Write ".selectColor {BORDER-RIGHT: #D4D0C8 1px solid; PADDING-RIGHT: 0px; BORDER-TOP: #D4D0C8 1px solid; PADDING-LEFT: 0px; PADDING-BOTTOM: 0px; MARGIN: 0px; VERTICAL-ALIGN: middle; BORDER-LEFT: #D4D0C8 1px solid; PADDING-TOP: 0px; BORDER-BOTTOM: #D4D0C8 1px solid;}"
			Response.Write ".dropdown {VERTICAL-ALIGN: middle;margin-top:2;margin-left:3;font-family:verdana; Color:#000000; font-size: 8pt;}"
			Response.Write "</style>"
		else
			Response.Write "<link href='"&s_stylesheetpath&"' type='text/css' rel='stylesheet'>"
		End If
	
	End Sub
	
	private Function GetControlFromName(StringName)  
	
		Select Case lcase(StringName)
		
		case "doubleLine":
			GetControlFromName = DoubleLine
		case "save":
			GetControlFromName =  SaveButton	
		case "new":
			GetControlFromName =  NewButton	
		case "print":
			GetControlFromName =  PrintButton	
		case "separator":
			GetControlFromName =  Separator	
		case "cut":
			GetControlFromName =  Cut	
		case "copy":
			GetControlFromName =  Copy
		case "paste":
			GetControlFromName =  Paste	
		case "pastetext":
			GetControlFromName =  PasteText	
		case "pasteword":
			GetControlFromName =  PasteWord	
		case "delete":
			GetControlFromName =  Delete	
		case "undo":
			GetControlFromName =  Undo
		case "redo":
			GetControlFromName =  Redo
		case "selectall":
			GetControlFromName =  SelectAll
		case "g_start":
			GetControlFromName =  G_Start
		case "toggleborder":
			GetControlFromName =  ToggleBorder
		case "absoluteposition":
			GetControlFromName =  AbsolutePosition
		case "g_end":
			GetControlFromName =  G_End
		case "hr":
			GetControlFromName =  Hr
		case "link":
			GetControlFromName =  Link
		case "unlink":
			GetControlFromName =  UnLink
		case "downloadablefiles":
			GetControlFromName =  DownloadableFiles
		case "char":
			GetControlFromName =  Char
		case "emotion":
			GetControlFromName =  Emotion
		case "inserttext":
			GetControlFromName =  InsertText
		case "imagegallery":
			GetControlFromName =  ImageGallery
		case "externalimage":
			GetControlFromName =  ExternalImage
		case "flashgallery":
			GetControlFromName =  FlashGallery			
		case "forward":
			GetControlFromName =  Forward
		case "backward":
			GetControlFromName =  Backward
		case "inserttable":
			GetControlFromName =  InsertTable
		case "addrow":
			GetControlFromName =  AddRow
		case "deleterow":
			GetControlFromName =  DeleteRow
		case "addcolumn":
			GetControlFromName =  AddColumn
		case "deletecolumn":
			GetControlFromName =  DeleteColumn
		case "addcell":
			GetControlFromName =  AddCell
		case "deletecell":
			GetControlFromName =  DeleteCell
		case "mergecell":
			GetControlFromName =  MergeCell
		case "splitcell":
			GetControlFromName =  SplitCell
		case "break":
			GetControlFromName =  Break
		case "doubleline":
			GetControlFromName =  DoubleLine
		case "paragraphdropdown":		
			GetControlFromName =  ParagraphDropDown
		case "styledropdown":
			GetControlFromName =  StyleDropdown
		case "fontdropdown":
			GetControlFromName =  fontDropDown
		case "sizedropdown":
			GetControlFromName =  sizeDropDown
		case "codesnippetdropdown":
			GetControlFromName =  codesnippetDropDown
		case "imagesdropdown":
			GetControlFromName =  imagesDropDown
		case "linksdropdown":
			GetControlFromName =  linksDropDown
		case "zoomdropdown":
			GetControlFromName =  zoomDropDown
		case "bold":
			GetControlFromName =  Bold
		case "italic":
			GetControlFromName =  Italic
		case "underline":
			GetControlFromName =  Underline
		case "justifyleft":
			GetControlFromName =  JustifyLeft	
		case "justifycenter":
			GetControlFromName =  JustifyCenter
		case "justifyright":
			GetControlFromName =  JustifyRight
		case "fontcolor":
			GetControlFromName =  FontColor	
		case "highlight":
			GetControlFromName =  HighLight	
		case "insertorderedlist":
			GetControlFromName =  InsertOrderedList	
		case "insertunorderedlist":
			GetControlFromName =  InsertUnorderedList		
		case "indent":
			GetControlFromName =  Indent			
		case "outdent":
			GetControlFromName =  Outdent					
		case "subscript":
			GetControlFromName =  Subscript					
		case "superscript":
			GetControlFromName =  Superscript					
		case "strikethrough":
			GetControlFromName =  Strikethrough					
		case "removeformat":
			GetControlFromName =  RemoveFormat	
		case "cleanupcode":
			GetControlFromName =  CleanupCode
		case "selectnone":
			GetControlFromName =  SelectNone	
		case "justifynone":
			GetControlFromName =  JustifyNone
		case "justifyfull":
			GetControlFromName =  JustifyFull		
		case "insertdate":
			GetControlFromName =  InsertDate	
		case "inserttime":
			GetControlFromName =  InsertTime	
		case "help":
			GetControlFromName =  Help	
		Case Else					
			GetControlFromName =  Separator
		
		End Select
	
	End Function	
		
	Public Sub Draw()
		Call DetermineRenderClientScript
		Call GetdlgHelper
		If(s_renderClientScript) Then
			Call editorClientScript ()
			Call editorStylesheet ()
			Call Toolbars_Initialize()
			Response.Write ("<input name="""&ID&"_HTMLContent"" id="""&ID&"_HTMLContent"" type=""hidden"" value=""" & Server.HTMLEncode( s_Text ) & """/>")
			Response.Write("<div id="""&ID&"_container"" style=""width:"&s_width&" "" class=""container"">")
			Response.Write("<div id="""&ID&"_toolbar"" style=""margin-left:1px;"" onmouseup=""m_up();"" onmousedown=""m_down();"" onmouseover=""m_over();"" onmouseout=""m_out();"" onselectstart=""doFalse()"" ondragstart=""doFalse()"">")
			Call CreateToolBar()
			if CustomAddons <> "" then
				Response.Write CustomAddons
			end if
			Response.Write("</div>")
			Response.Write ("<div id="""&ID&"_editBox"" onpaste=""oneditorpaste("&ID&");""  style=""width: "&s_width&"; height:"&s_height&";"" class=""editBox"" >")
			Response.Write s_Text
			Response.Write("</div>")
			
			Response.Write ("<Div id="""&ID&"_sandbox"" style=""VISIBILITY: hidden; OVERFLOW: hidden; POSITION: absolute; WIDTH: 1px; HEIGHT: 1px;""></Div>")
			
			Response.Write("<div id="""&ID&"_bottombar"" onmouseup=""m_up();"" onmousedown=""m_down();"" onmouseover=""m_over();"" onmouseout=""m_out();"" onselectstart=""doFalse()"" ondragstart=""doFalse()"" style=""margin-top:0;margin-left:3;margin-right:0;margin-bottom:0;padding:0;"">")
			If (s_showBottomBar) Then
				Call BuildBottomBar ()
			End If
			Response.Write("</div>")
			Response.Write("</div>")
			Call AddClientScript ()
		Else
			Response.Write "<TEXTAREA name="""&ID&"_HTMLContent"" rows="""&s_textareaRows&""" cols="""&s_textareaCols&""" style=""WIDTH: " & s_width & "; HEIGHT: " & s_height & """>" & Server.HTMLEncode( s_Text ) & "</TEXTAREA>"
		End If
	End Sub
	
	Private Property Get SaveButton
		dim saveimage_url
		saveimage_url = GetURL("save.gif")		
		SaveButton = Response.Write ("<INPUT type=""image"" onclick=""save("&ID&")"" src="""&saveimage_url&""" name=""Save"" alt=""Save"" class=""button"" onmouseup=""m_up();"" onmousedown=""m_down();"" onmouseover=""m_over();"" onmouseout=""m_out();"">")
	End Property
	
	Private Property Get NewButton
		NewButton = Create_Btn("_Format("&ID&",'New')",GetURL("newdoc.gif"), "New",20,20)
	End Property
	Private Property Get PrintButton
		PrintButton = Create_Btn("_Format("&ID&",'Print')",GetURL("print.gif"), "Print",20,20)
	End Property
	Private Property Get Separator
		Separator = Create_Sep(GetURL("space.gif"),6,18)
	End Property
	Private Property Get Cut
		Cut = Create_Btn("_Format("&ID&",'Cut')",GetURL("cut.gif"), "Cut",20,20)
	End Property
	Private Property Get Copy
		Copy  = Create_Btn("_Format("&ID&",'Copy')",GetURL("Copy.gif"), "Copy",20,20)
	End Property
	Private Property Get Paste
		Paste = Create_Btn("_Format("&ID&",'Paste')",GetURL("Paste.gif"), "Paste",20,20)
	End Property
	Private Property Get PasteText
		PasteText = Create_Btn("_Format("&ID&",'PasteText')",GetURL("PasteText.gif"), "PasteText",20,20)
	End Property
	Private Property Get PasteWord
		PasteWord = Create_Btn("_Format("&ID&",'PasteWord')",GetURL("PasteWord.gif"), "PasteWord",20,20)
	End Property
	Private Property Get Delete
		Delete = Create_Btn("_Format("&ID&",'Delete')",GetURL("Delete.gif"), "Delete",20,20)
	End Property
	Private Property Get Undo
		Undo = Create_Btn("_Format("&ID&",'Undo')",GetURL("Undo.gif"), "Undo",20,20)
	End Property
	Private Property Get Redo
		Redo = Create_Btn("_Format("&ID&",'Redo')",GetURL("Redo.gif"), "Redo",20,20)
	End Property
	Private Property Get SelectAll
		SelectAll = Create_Btn("_Format("&ID&",'SelectAll')",GetURL("SelectAll.gif"), "Select All",20,20)
	End Property
	Private Property Get ToggleBorder
		ToggleBorder = Create_Btn("_Format("&ID&",'Toggleborder')",GetURL("borders.gif"), "Visible Borders",20,20)
	End Property
	Private Property Get AbsolutePosition
		AbsolutePosition = Create_Btn("_Format("&ID&",'AbsolutePosition')",GetURL("abspos.gif"), "Position Absolutely",20,20)
	End Property
	Private Property Get Hr
		Hr = Create_Btn("_Format("&ID&",'InsertHorizontalRule')",GetURL("rule.gif"), "Insert Line",20,20)
	End Property
	Private Property Get Link
		Link = Create_Btn("_Format("&ID&",'Insert_link')",GetURL("Link.gif"), "Insert Link",20,20)
	End Property
	Private Property Get UnLink
		UnLink = Create_Btn("_Format("&ID&",'UnLink')",GetURL("UnLink.gif"), "Remove Link",20,20)
	End Property
	Private Property Get DownloadableFiles
		DownloadableFiles = Create_Btn("_Format("&ID&",'DownloadableFiles')",GetURL("document.gif"), "Downloadable Files",20,20)
	End Property
	Private Property Get Char
		Char = Create_Btn("_Format("&ID&",'Char')",GetURL("specialchar.gif"), "Special characters",20,20)
	End Property
	Private Property Get Emotion
		Emotion = Create_Btn("_Format("&ID&",'Emotion')",GetURL("Emotion.gif"), "Insert Emotions",20,20)
	End Property
	Private Property Get InsertText
		InsertText = Create_Btn("_Format("&ID&",'Insert_Text')",GetURL("text.gif"), "Insert, edit, or reposition text regions",20,20)
	End Property
	Private Property Get ImageGallery
		ImageGallery = Create_Btn("_Format("&ID&",'Insert_Image')",GetURL("image.gif"), "Insert Local Image",20,20)
	End Property
	Private Property Get ExternalImage
		ExternalImage = Create_Btn("_Format("&ID&",'InsertImage')",GetURL("eximage.gif"), "Insert Link to External Image",20,20)
	End Property
	Private Property Get FlashGallery
		FlashGallery = Create_Btn("_Format("&ID&",'Insert_Flash')",GetURL("flash.gif"), "Insert Flash",20,20)
	End Property
	Private Property Get Forward
		Forward = Create_Btn("_Format("&ID&",'Forward')",GetURL("Forward.gif"), "Bring Forward",20,20)
	End Property
	Private Property Get Backward
		Backward = Create_Btn("_Format("&ID&",'Backward')",GetURL("Backward.gif"), "Send Backward",20,20)
	End Property
	Private Property Get InsertTable
		InsertTable = Create_Btn("_Format("&ID&",'Table')",GetURL("instable.gif"), "Insert Table",20,20)
	End Property
	Private Property Get AddRow
		AddRow = Create_Btn("doRow("&ID&",'add')",GetURL("insrow.gif"), "Insert Row",20,20)
	End Property
	Private Property Get DeleteRow
		DeleteRow = Create_Btn("doRow("&ID&",'delete')",GetURL("Delrow.gif"), "Delete Rows",20,20)
	End Property
	Private Property Get AddColumn
		AddColumn = Create_Btn("doColumn("&ID&",'add')",GetURL("Inscol.gif"), "Insert Column",20,20)
	End Property
	Private Property Get DeleteColumn
		DeleteColumn = Create_Btn("doColumn("&ID&",'delete')",GetURL("Delcol.gif"), "Delete Columns",20,20)
	End Property
	Private Property Get AddCell
		AddCell = Create_Btn("doCell("&ID&",'add')",GetURL("Inscell.gif"), "Insert Cell",20,20)
	End Property
	Private Property Get DeleteCell
		DeleteCell = Create_Btn("doCell("&ID&",'delete')",GetURL("Delcell.gif"), "Delete Cells",20,20)
	End Property
	Private Property Get MergeCell
		MergeCell = Create_Btn("doCell("&ID&",'merge')",GetURL("Mrgcell.gif"), "Merge Cells",20,20)
	End Property
	Private Property Get SplitCell
		SplitCell = Create_Btn("doCell("&ID&",'split')",GetURL("Spltcell.gif"), "Split Cells",20,20)
	End Property
	Private Property Get Bold
		Bold = Create_Btn("_Format("&ID&",'Bold')",GetURL("Bold.gif"), "Bold",20,20)
	End Property
	Private Property Get Italic
		Italic = Create_Btn("_Format("&ID&",'Italic')",GetURL("Italic.gif"), "Italic",20,20)
	End Property
	Private Property Get Underline
		Underline = Create_Btn("_Format("&ID&",'Underline')",GetURL("Under.gif"), "Underline",20,20)
	End Property
	Private Property Get JustifyLeft
		JustifyLeft = Create_Btn("_Format("&ID&",'JustifyLeft','','p align=left')",GetURL("left.gif"), "Left Justify",20,20)
	End Property
	Private Property Get JustifyCenter
		JustifyCenter = Create_Btn("_Format("&ID&",'JustifyCenter','','p align=center')",GetURL("center.gif"), "Center",20,20)
	End Property
	Private Property Get JustifyRight
		JustifyRight = Create_Btn("_Format("&ID&",'JustifyRight','','p align=right')",GetURL("right.gif"), "Right Justify",20,20)
	End Property
	Private Property Get FontColor
		FontColor = Create_ColorBtn("_Format("&ID&",'ForeColor',"&ID&"_forecolorimg.style.backgroundColor)",GetURL("fontcolor.gif"),"Font Color",""&ID&"_forecolorimg","BACKGROUND-COLOR: red;")
		FontColor = FontColor & Create_ColorBtn("SelectColor("&ID&","&ID&"_forecolorimg);_Format("&ID&",'ForeColor',"&ID&"_forecolorimg.style.backgroundColor)",GetURL("tbdown.gif"),"Set Font Color","Set_forecolorimg","Width:9")
	End Property
	Private Property Get HighLight
		HighLight = Create_ColorBtn("_Format("&ID&",'BackColor',"&ID&"_bkcolorimg.style.backgroundColor)",GetURL("colorpen.gif"),"Highlight",""&ID&"_bkcolorimg","BACKGROUND-COLOR: yellow;")
		HighLight = HighLight & Create_ColorBtn("SelectColor("&ID&","&ID&"_bkcolorimg);_Format("&ID&",'BackColor',"&ID&"_bkcolorimg.style.backgroundColor)",GetURL("tbdown.gif"),"Set Highlight","Set_backcolorimg","Width:9")
	End Property
	Private Property Get InsertOrderedList
		InsertOrderedList = Create_Btn("_Format("&ID&",'InsertOrderedList')",GetURL("NumList.gif"), "Insert Numbered List",20,20)
	End Property
	Private Property Get InsertUnorderedList
		InsertUnorderedList = Create_Btn("_Format("&ID&",'InsertUnorderedList')",GetURL("bullist.gif"), "Insert Unordered List",20,20)
	End Property
	Private Property Get Indent
		Indent = Create_Btn("_Format("&ID&",'Indent')",GetURL("Indent.gif"), "Indent",20,20)
	End Property
	Private Property Get Outdent
		Outdent = Create_Btn("_Format("&ID&",'Outdent')",GetURL("Outdent.gif"), "Outdent Text",20,20)
	End Property
	Private Property Get Subscript
		Subscript = Create_Btn("_Format("&ID&",'Subscript')",GetURL("Subscript.gif"), "Subscript Text",20,20)
	End Property
	Private Property Get Superscript
		Superscript = Create_Btn("_Format("&ID&",'Superscript')",GetURL("Superscript.gif"), "Superscript Text",20,20)
	End Property
	Private Property Get Strikethrough
		Strikethrough = Create_Btn("_Format("&ID&",'Strikethrough')",GetURL("strike.gif"), "Strikethrough Text",20,20)
	End Property
	Private Property Get RemoveFormat
		RemoveFormat = Create_Btn("_Format("&ID&",'RemoveFormat')",GetURL("Unformat.gif"), "Remove Format",20,20)
	End Property
	Private Property Get CleanupCode
		CleanupCode = Create_Btn("_Format("&ID&",'CleanupCode')",GetURL("cleanup.gif"), "Code Cleaner",20,20)
	End Property
	Private Property Get SelectNone
		SelectNone = Create_Btn("_Format("&ID&",'unselect')",GetURL("selectnone.gif"), "Select None",20,20)
	End Property
	Private Property Get JustifyNone
		JustifyNone = Create_Btn("_Format("&ID&",'JustifyNone')",GetURL("justifynone.gif"), "Justify None",20,20)
	End Property		
	Private Property Get JustifyFull
		JustifyFull = Create_Btn("_Format("&ID&",'JustifyFull')",GetURL("justifyfull.gif"), "Justify Full",20,20)
	End Property	
	Private Property Get InsertDate
		InsertDate = Create_Btn("_Format("&ID&",'InsertDate')",GetURL("InsertDate.gif"), "Insert today's date",20,20)
	End Property
	Private Property Get InsertTime
		InsertTime = Create_Btn("_Format("&ID&",'InsertTime')",GetURL("timer.gif"), "Insert the current time",20,20)
	End Property
	Private Property Get Help
		dim temp
		if s_helpurl = "" or s_helpurl = "null" then
			temp = "http://aspedit.net/tourforendusers.asp"
		else
			temp = s_helpurl
		end if
		dim helpimage_url
		helpimage_url = "help.gif"		
		Help = Response.Write ("<img src='"&GetURL(helpimage_url)&"' title='Help' onclick=window.open('" & temp & "') type=""btn""  class=""button"" width=""20"" height=""20"" border=""0"">")
	End Property
	Private Property Get G_Start
		G_Start = Response.Write ("<nobr>")
	End Property
	Private Property Get G_End
		G_End = Response.Write ("</nobr>")
	End Property
	Private Property Get Break
		Break = Response.Write ("<br>")
	End Property
	Private Property Get DoubleLine
		DoubleLine = Create_Sep(GetURL("doubleline.gif"),9,20)
	End Property
	Private Property Get paragraphDropDown
		Dim temp
		temp = ""
		temp = temp&"<select onChange=""_Format("&ID&",'formatBlock',this.options[this.selectedIndex].value); this.selectedIndex=0;"" style=""width: "&ParagraphsDropDownWidth&""" class=dropdown>"
		temp = temp&"<option value=""Paragraph"">Paragraph</option>"
		dim list_array
		list_array = split(ParagraphsList, ",") 
		if IsArray(list_array) then
			if not IsArrayEmpty(list_array) then
				For i=0 to Ubound(list_array)
					temp = temp&"<option value='"&list_array(i)&"'>"&list_array(i)&"</option>"
				Next
			end if
		end if 
		temp = temp&"</select>"			
		paragraphDropDown = Response.Write (temp)
	End Property
	Private Property Get fontDropDown
		Dim temp
		temp = ""
		temp = temp&"<select OnChange=""_Format("&ID&",'fontname',this.options[this.selectedIndex].value);this.selectedIndex=0;"" style=""width: "&FontsDropDownWidth&""" class=dropdown>"
		temp = temp&"<option value=""Font"">Font</option>"
		dim list_array
		list_array = split(FontFacesList, ",") 
		if IsArray(list_array) then
			if not IsArrayEmpty(list_array) then
				For i=0 to Ubound(list_array)
					temp = temp&"<option value='"&list_array(i)&"'>"&list_array(i)&"</option>"
				Next
			end if
		end if 
		temp = temp&"</select>"	
		fontDropDown = Response.Write (temp)
	End Property
	Private Property Get sizeDropDown
		Dim temp
		temp = ""
		temp = temp&"<select OnChange=""_Format("&ID&",'fontsize',this.options[this.selectedIndex].value);this.selectedIndex=0;"" style=""width: "&SizesDropDownWidth&""" class=dropdown>"
		temp = temp&"<option value=""Size"">Size</option>"
		dim list_array
		list_array = split(FontSizesList, ",") 
		if IsArray(list_array) then
			if not IsArrayEmpty(list_array) then
				For i=0 to Ubound(list_array)
					temp = temp&"<option value='"&list_array(i)&"'>"&list_array(i)&"</option>"
				Next
			end if
		end if 
		temp = temp&"</select>"				
		sizeDropDown = Response.Write (temp)
	End Property				
	Private Property Get zoomDropDown
		Dim temp
		temp = ""
		temp = temp&"<select OnChange=""_Format("&ID&",'zoom',this.options[this.selectedIndex].value);this.selectedIndex=0;""  style=""width: "&ZoomsDropDownWidth&""" class=dropdown>"
		temp = temp&"<option value=""Zoom"">Zoom</option>"
		dim list_array
		list_array = split(ZoomsList, ",") 
		if IsArray(list_array) then
			if not IsArrayEmpty(list_array) then
				For i=0 to Ubound(list_array)
					temp = temp&"<option value='"&list_array(i)&"'>"&list_array(i)&"</option>"
				Next
			end if
		end if 
		temp = temp&"</select>"			
		zoomDropDown = Response.Write (temp)
	End Property
	Private Property Get styleDropDown
		Dim temp,name_array,list_array,i
		temp = ""
		name_array = Split(s_styledropdownMenuNames,",")
		list_array = Split(s_styledropdownMenuList,",")
		temp = temp&"<select OnChange=""_Format("&ID&",'setStyle',this.options[this.selectedIndex].value); this.selectedIndex=0;"" style=""width: "&StylesDropDownWidth&""" class=dropdown>"
		temp = temp&"<option value=""Style"">Style</option>"
		if IsArray(name_array) and IsArray(list_array) then
			if not IsArrayEmpty(list_array) then
				For i=0 to Ubound(list_array)
					temp = temp&"<option value='"&list_array(i)&"'>"&name_array(i)&"</option>"
				Next
			end if
		end if 
		temp = temp&"</select>"
		
		styleDropDown = Response.Write (temp)
	End Property
	Private Property Get codesnippetDropDown
		Dim temp,name_array,list_array,i
		temp = ""
		name_array = split(s_codesnippetdropdownMenuNames, ",") 
		list_array = split(s_codesnippetdropdownMenuList, ",") 
		temp = temp&"<select OnChange=""_Format("&ID&",'insertHTML',this.options[this.selectedIndex].value);this.selectedIndex=0;"" style=""width: "&CodeSnippetsDropDownWidth&""" class=dropdown>"
		temp = temp&"<option value=""Code Snippet"">Code Snippet</option>"
		if IsArray(name_array) and IsArray(list_array) then
			if not IsArrayEmpty(list_array) then
				For i=0 to Ubound(list_array)
					temp = temp&"<option value='"&list_array(i)&"'>"&name_array(i)&"</option>"
				Next
			end if
		end if 
		temp = temp&"</select>"
		
		codesnippetDropDown = Response.Write (temp)
	End Property
	Private Property Get imagesDropdown
		Dim temp,name_array,list_array,i
		temp = ""
		name_array = split(s_imagesdropdownMenuNames, ",") 
		list_array = split(s_imagesdropdownMenuList, ",") 
		temp = temp&"<select OnChange=""_Format("&ID&",'insertImage',this.options[this.selectedIndex].value);this.selectedIndex=0;"" style=""width: "&ImagesDropDownWidth&""" class=dropdown>"
		temp = temp&"<option value=""Images"">Images</option>"
		if IsArray(name_array) and IsArray(list_array) then
			if not IsArrayEmpty(list_array) then
				For i=0 to Ubound(list_array)
					temp = temp&"<option value='"&list_array(i)&"'>"&name_array(i)&"</option>"
				Next
			end if
		end if 
		temp = temp&"</select>"		
		imagesdropdown = Response.Write (temp)
	End Property
	Private Property Get linksDropDown
		Dim temp,name_array,list_array,i
		temp = ""
		name_array = split(s_linksdropdownMenuNames, ",") 
		list_array = split(s_linksdropdownMenuList, ",") 
		temp = temp&"<select OnChange=_Format("&ID&",'insertLink',this.options[this.selectedIndex].value,this.options[this.selectedIndex].text)  style=""width: "&LinksDropDownWidth&""" class=dropdown>"
		temp = temp&"<option value=""Links"">Links</option>"
		if IsArray(name_array) and IsArray(list_array) then
			if not IsArrayEmpty(list_array) then
				For i=0 to Ubound(list_array)
					temp = temp&"<option value='"&list_array(i)&"'>"&name_array(i)&"</option>"
				Next
			end if
		end if 
		temp = temp&"</select>"		
		linksDropDown = Response.Write (temp)
	End Property
	
	Private Property Get GetURL(imageURL)
		GetURL = ""&s_filespath&"/"&imageURL	
	End Property
	
	private Sub GetdlgHelper 
		Response.Write "<OBJECT id=dlgHelper_"&ID&" CLASSID='clsid:3050f819-98b5-11cf-bb82-00aa00bdce0b' width=0px height=0px VIEWASTEXT></OBJECT>"
	End Sub

End Class

Public Function Create_Btn(command, imageURL, cellID,l_width,l_height)
	If IsNumeric(l_width) and IsNumeric(l_height) Then	
		Create_Btn = Response.Write ("<img title="""&cellID&""" class=""button"" onclick="""&command&";"" type=""btn"" src='"&imageURL&"' width="&l_width&" height="&l_height&" border=0 />")
	Else
		Create_Btn = Response.Write ("<img title="""&cellID&""" class=""button"" onclick="""&command&";"" type=""btn"" src='"&imageURL&"' border=0 />")
	End If
End Function

Public Function Create_Sep(imageURL,width,height)
	Create_Sep = Response.Write ("<img class='spacer' src='"&imageURL&"' border='0' />")
End Function

Public Function Create_ColorBtn(command, imageURL, cellID, ImageID, imageStyle)
	Create_ColorBtn = Response.Write ("<img id="""&ImageID&""" style="""&imageStyle&""" title="""&cellID&""" class=""SelectColor"" onclick="""&command&";"" type=""btn"" src='"&imageURL&"' border=""0"" />")
End Function

Private Function GetString(command)
	GetString = command	
End Function

Private Function IsArrayEmpty(varArray)
   Dim lngUBound
   On Error Resume Next
   lngUBound = UBound(varArray)
   If Err.Number <> 0 Then
      IsArrayEmpty = True
   Else
      IsArrayEmpty = False
   End If
End Function

%>