<%
'**************************************************************************************
'* Application: ActionCalendar
'* Version: 1.3
'* Author: Andrew L. Warren
'* Email: andy@warrenstudios.com
'* Publish Date: 03/01/2001
'* Updated: 01/26/2002
'* Copyright: (c) 2001 - 2002 Warren Studios, ALW. All Rights Reserved
'*
'* Warranties and Terms of Use Agreement:
'*   No warranties, implied or otherwise, are made regarding the usage of ActionCalendar
'*   and it's associated code. The users assumes all risk and the Author of
'*   ActionCalendar is in no part liable for any incurred damages. Execution of this
'*   code in part or whole constitutes acceptance of the Terms and Agreement for use.
'**************************************************************************************

'**************************************************************************************
'* Function Name: BuildCalendar()                                                     *
'*         Input: Any valid date expression, valid string, empty string.              *
'*        Output: HTML string of the calendar table. Calls GetRequest(), GetEvent().  *
'*    User Edits: Change the # CONFIGURATION OPTIONS # below if you want to customize *
'*                the file name and table options.                                    *
'**************************************************************************************
Function BuildCalendar(srcDate,size)
	'*** Declare the function variables ***
	Dim objFirstDOM		' first day of month
	Dim objLastDOM		' last day of month
	Dim intDayCount		' increment value for day of week
	Dim intDateCount	' increment value for date of month
	Dim objDateDisplay	' calendar display date
	Dim strTable		' HTML string
	Dim strEventText	' HTML string for event
	Dim intHeight		' height for table cells
	Dim intWidth		' width for table cells
	Dim intTblBorder	' table border
	Dim intTblCpad 		' cellpadding
	Dim intTblCspc		' cellspacing
	Dim strTip  		' tool tip message (IE only)
	Dim i				' Loop counter
	Dim intPrevMth		' previous month
	Dim intNextMth		' next month
	Dim intPrevYear		' previous year
	Dim intNextYear		' next year
	Dim objBOW			' beginning of week
	Dim objEOW			' end of week
	Dim objPrevWeek		' previous week
	Dim objNextWeek		' next week
	
	If GetRequest("view") = "weekly" Then
		size = "large"
	End If
	
	'##################################################################
	'################ CONFIGURATION OPTIONS FOR YOU ###################
	intTblBorder = 0			' table border
	intTblCpad   = 2			' cellpadding
	intTblCspc	 = 1			' cellspacing
	strTip       = "Click for Event Details"		' set to an empty string ("") to disable tool tip
	
	'*** Check for Administration View ***
	If GetRequest("action") = "admin" Then
		size 		= "large"						' the admin page MUST be set to the "large" size
		strTip      = "Click to Add a New Event"	' set to an empty string ("") to disable tool tip
	End If

	'*** Set the size of the Calendar table ***
	Select Case size
		Case "small"
			intHeight = 10
			intWidth  = 10
		Case "med"
			intHeight = 30
			intWidth  =	30	
		Case "large"
			intHeight = 80
			intWidth  =	80
		Case "view"
			intHeight = 200
			intWidth  =	200
		Case Else
			intHeight = 30
			intWidth  =	30	
			size      = "med"
	End Select
	'############### END CONFIGURATION OPTIONS FOR YOU ################
	'###### YOU SHOULD NOT HAVE TO EDIT ANYTHING BELOW THIS LINE ######
	'##################################################################
	
	'*** Set the First and Last Day's of the Month ***
	'*** Use line below for English (mm/dd/yyyy) date format
	objFirstDOM = CDate(Month(srcDate) & "/1/" & Year(srcDate))
	'*** Use line below for European (dd/mm/yyyy) date format
	'objFirstDOM = CDate("1/" & Month(srcDate) & "/" & Year(srcDate))
	objLastDOM  = DateAdd("d", -1, DateAdd("m", 1, objFirstDOM))

	intPrevMth  = Month(srcDate)-1
	intPrevYear = Year(srcDate)
	If intPrevMth <= 0 Then
		intPrevMth  = 12
		intPrevYear = Year(DateAdd("yyyy", -1, srcDate))
	End If
	intNextMth  = Month(srcDate)+1
	intNextYear = Year(srcDate)
	If intNextMth > 12 Then
		intNextMth  = 1
		intNextYear = Year(DateAdd("yyyy", 1, srcDate))
	End If
	
	'*** Set the Day, Date counters and Calendar Date ***
	intDayCount    = intStartDay
	intDateCount   = intStartDay
	objDateDisplay = objFirstDOM	

	If GetRequest("view") = "weekly" Then
		objBOW = GetRequest("date")
		
		Do Until WeekDay(objBOW) = intStartDay
			objBOW = DateAdd("d",-1,objBOW)
		Loop
		
		objEOW = DateAdd("d",6,objBOW)
		objPrevWeek = DateAdd("d",-1,objBOW)
		objNextWeek = DateAdd("d",1,objEOW)
		
		If Month(objBOW) <> Month(objEOW) Then
			If Month(GetRequest("date")) <> Month(objBOW) Then
				objPrevWeek = objBOW
			ElseIf Month(GetRequest("date")) <> Month(objEOW) Then
				objNextWeek = objEOW
			End If
		End If

		objDateDisplay = objBOW
		objLastDOM = objEOW
	End If	
	
	'*** Build the Calendar Event View ***
	If size = "view" Then
		strTable = "<table class=fill border=" & intTblBorder & " cellpadding=" & intTblCpad & " cellspacing=" & intTblCspc & " width=""100%"">" & VbCrLf &_
		"<tr class=header>" & VbCrLf
	
		strEventText = GetView(GetRequest("date"))
		strTable = strTable & "<th>Events for " & UCase(strMonth(Month(srcDate)-1)) & " " & Day(srcDate) & ", " & Year(srcDate) & "</th>" & VbCrLf &_
		"</tr>" & VbCrLf &_
		"<tr>" & VbCrLf &_
		"<td valign=top class=default><table border=0 width=100% cellpadding=0 cellspacing=0>" & strEventText &_
		"</table></td>" & VbCrLf
		strEventText = ""
	'*** Build the Calendar View ***
	Else
		If GetRequest("action") <> "admin" Then
			strTable = strTable & "<table class=fill border=" & intTblBorder & " cellpadding=" & intTblCpad & " cellspacing=" & intTblCspc & ">" & VbCrLf &_
			"<tr class=header>" & VbCrLf &_
			"<th>&nbsp;<a class=header_link href=" & strFileName & "?date=" & srcDate & "&size=large><font face=Tahoma size=2><b>Month View</b></font></a>&nbsp;</th>" & VbCrLf &_
			"<th>&nbsp;<a class=header_link href=" & strFileName & "?date=" & srcDate & "&view=weekly><font face=Tahoma size=2><b>Week View</b></font></a>&nbsp;</th>" & VbCrLf &_
			"<th>&nbsp;<a class=header_link href=" & strFileName & "?date=" & srcDate & "&view=print><font face=Tahoma size=2><b>Print View</b></font></a>&nbsp;</th>" & VbCrLf &_
			"</tr></table>" & VbCrLf
		End If
		'*** Build the Month header for the Calendar ***
		strTable = strTable & "<table class=fill border=" & intTblBorder & " cellpadding=" & intTblCpad & " cellspacing=" & intTblCspc & ">" & VbCrLf &_
		"<tr class=header>" & VbCrLf &_
		"<th>"
		
		If GetRequest("view") = "weekly" Then
			strTable = strTable & "<a class=header_link href=" & strFileName & "?date=" & objPrevWeek & "&view=weekly>" &_
			"<b>&lt;</b>" &_
			"</a></th>" & VbCrLf &_
			"<th colspan=5>"
			If Month(objPrevWeek) <> Month(GetRequest("date")) Then
				strTable = strTable & "Week of " & Month(GetRequest("date")) & "/1/" & Right(Year(GetRequest("date")),2)
			Else
				strTable = strTable & "Week of " & objBOW
			End If
			strTable = strTable & "</th>" & VbCrLf &_
			"<th>" &_
			"<a class=header_link href=" & strFileName & "?date=" & objNextWeek & "&view=weekly>" &_
			"<b>&gt;</b>"
		Else
			strTable = strTable & "<a class=header_link href=" & strFileName & "?date=" & intPrevMth & "/" & intPrevYear & "&size=" & size & "&action=" & GetRequest("action") & ">"
			If size = "small" Then
				strTable = strTable & "<b>&lt;</b>"
			Else
				strTable = strTable & Left(strMonth(intPrevMth-1),3)
			End If
			strTable = strTable & "</a></th>" & VbCrLf &_
			"<th colspan=5>" & UCase(strMonth(Month(srcDate)-1)) & " - " & Year(srcDate) & "</th>" & VbCrLf &_
			"<th>" &_
			"<a class=header_link href=" & strFileName & "?date=" & intNextMth & "/" & intNextYear & "&size=" & size & "&action=" & GetRequest("action") & ">"
			If size = "small" Then
				strTable = strTable & "<b>&gt;</b>"
			Else
				strTable = strTable & Left(strMonth(intNextMth-1),3)
			End If
		End If
		
		strTable = strTable & "</a></th>" & VbCrLf &_
		"</tr>" & VbCrLf &_
		"<tr>" & VbCrLf	
		
		'*** Build the Day header for the Calendar ***
		For i = 1 To 7
			If intDayCount > 7 Then
				intDayCount = 1
			End If
			
			strTable = strTable & "<th>"

			If size = "small" Then
				strTable = strTable & UCase(Left(WeekDayName(intDayCount,1),1))
			Else
				strTable = strTable & UCase(WeekDayName(intDayCount,1))
			End If

			strTable = strTable & "</th>" & VbCrLf
			intDayCount = intDayCount + 1
		Next
		
		strTable = strTable & "</tr>" & VbCrLf
		
		'*** Build the Rows for the Calendar ***
		Do While DateDiff("d", objDateDisplay, objLastDOM) => 0

			strTable = strTable & "<tr>" & VbCrLf
			
			For i = 1 To 7
				If (Month(GetRequest("date")) <> Month(objDateDisplay)) And (GetRequest("view") = "weekly") Then
					strTable = strTable & "<td height=" & intHeight & " width=" & intWidth & ">&nbsp;</td>" & VbCrLf
					objDateDisplay = DateAdd("d", 1, objDateDisplay)
				ElseIf (intDateCount < WeekDay(objDateDisplay)) Or (DateDiff("d", objDateDisplay, objLastDOM) < 0) Then
					strTable = strTable & "<td height=" & intHeight & " width=" & intWidth & ">&nbsp;</td>" & VbCrLf
				'*** Else write the date to the calendar table ***
				Else
					strEventText = GetEvent(objDateDisplay)
					strTable = strTable & "<td valign=top"
					'*** highlight today's cell ***
					If objDateDisplay = Date Then
						strTable = strTable & " class=today"
					'*** highlight event cell ***
					ElseIf strEventText <> "" Then
						strTable = strTable & " class=event"
					Else
						strTable = strTable & " class=default"
					End If
					strTable = strTable & " height=" & intHeight & " width=" & intWidth & ">"
					
					If size = "large" Then
						If GetRequest("action") = "admin" Then
							strTable = strTable & "<a class=event_link href=" & strFileName & "?date=" & objDateDisplay & "&view=yes&size=" & size & "&event_id=0&action=admin title=""" & strTip & """>" & Day(objDateDisplay) & "</a><br>"
						Else
							strTable = strTable & Day(objDateDisplay) & "<br>"
						End If
						If strEventText <> "" Then
							strTable = strTable & strEventText
							strEventText = ""
						End If
					Else
						If strEventText <> "" Then
							strTable = strTable & "<a class=event_link href=" & strFileName & "?date=" & objDateDisplay & "&view=yes&size=" & size & "&event_id=0 title=""" & strTip & """>" & Day(objDateDisplay) & "</a>"
							strEventText = ""
						Else
							strTable = strTable & Day(objDateDisplay)
						End If
					End If

					strTable = strTable & "</td>" & VbCrLf
					objDateDisplay = DateAdd("d", 1, objDateDisplay)
				End If
				intDateCount = intDateCount + 1
			Next
			strTable = strTable & "</tr>" & VbCrLf 
		Loop
		
	End If
	
	strTable =  strTable & "</tr>" & VbCrLf &_
				"</table>" & VbCrLf	
						
	BuildCalendar = strTable
End Function
%>